1. Уважаемые гости и пользователи форума.
    Администрация настоятельно рекомендует не регистрировать несколько аккаунтов для одного пользователя. При выявлении наличия мультиаккаунтов будут заблокированы все учетные записи данного пользователя.
    Аккаунты, зарегистрированные на временную почту будут также заблокированы.

Изменение пути при выборе компонентов

Тема в разделе "Nullsoft Scriptable Install System (NSIS)", создана пользователем JEKE24, 4 авг 2017.

  1. Пользователь

    Регистрация:
    15 авг 2016
    Сообщения:
    9
    Симпатии:
    7
    Пол:
    Мужской
    Всем доброго времени суток. Как можно осуществить изменение пути, при выборе из компонентов через RadioButton "Установка" и "Портативная версия".При котором при выборе установка путь был бы "$PROGRAMFILES\App" , а при выборе портативной версии он бы менялся на "$EXEDIR\App".
     
    Последнее редактирование: 4 авг 2017
  2. Пользователь

    Регистрация:
    15 авг 2016
    Сообщения:
    9
    Симпатии:
    7
    Пол:
    Мужской
    Код (C++):
    1.  
    2. !define NAME "foobarbaz"
    3. !define UNINSTKEY "${NAME}" ; Using a GUID here is not a bad idea
    4. !define DEFAULTNORMALDESTINATON "$ProgramFiles\${NAME}"
    5. !define DEFAULTPORTABLEDESTINATON "$Desktop\${NAME}"
    6. Name "${NAME}"
    7. Outfile "${NAME} setup.exe"
    8. RequestExecutionlevel highest
    9. SetCompressor LZMA
    10.  
    11. Var NormalDestDir
    12. Var PortableDestDir
    13. Var PortableMode
    14.  
    15. !include LogicLib.nsh
    16. !include FileFunc.nsh
    17. !include MUI2.nsh
    18.  
    19. !insertmacro MUI_PAGE_WELCOME
    20. Page Custom PortableModePageCreate PortableModePageLeave
    21. !insertmacro MUI_PAGE_DIRECTORY
    22. !insertmacro MUI_PAGE_INSTFILES
    23. !insertmacro MUI_PAGE_FINISH
    24. !insertmacro MUI_LANGUAGE English
    25.  
    26.  
    27. Function .onInit
    28. StrCpy $NormalDestDir "${DEFAULTNORMALDESTINATON}"
    29. StrCpy $PortableDestDir "${DEFAULTPORTABLEDESTINATON}"
    30.  
    31. ${GetParameters} $9
    32.  
    33. ClearErrors
    34. ${GetOptions} $9 "/?" $8
    35. ${IfNot} ${Errors}
    36.     MessageBox MB_ICONINFORMATION|MB_SETFOREGROUND "\
    37.      /PORTABLE : Extract application to USB drive etc$\n\
    38.      /S : Silent install$\n\
    39.      /D=%directory% : Specify destination directory$\n"
    40.     Quit
    41. ${EndIf}
    42.  
    43. ClearErrors
    44. ${GetOptions} $9 "/PORTABLE" $8
    45. ${IfNot} ${Errors}
    46.     StrCpy $PortableMode 1
    47.     StrCpy $0 $PortableDestDir
    48. ${Else}
    49.     StrCpy $PortableMode 0
    50.     StrCpy $0 $NormalDestDir
    51.     ${If} ${Silent}
    52.         Call RequireAdmin
    53.     ${EndIf}
    54. ${EndIf}
    55.  
    56. ${If} $InstDir == ""
    57.     ; User did not use /D to specify a directory,
    58.     ; we need to set a default based on the install mode
    59.     StrCpy $InstDir $0
    60. ${EndIf}
    61. Call SetModeDestinationFromInstdir
    62. FunctionEnd
    63.  
    64.  
    65. Function RequireAdmin
    66. UserInfo::GetAccountType
    67. Pop $8
    68. ${If} $8 != "admin"
    69.     MessageBox MB_ICONSTOP "You need administrator rights to install ${NAME}"
    70.     SetErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
    71.     Abort
    72. ${EndIf}
    73. FunctionEnd
    74.  
    75.  
    76. Function SetModeDestinationFromInstdir
    77. ${If} $PortableMode = 0
    78.     StrCpy $NormalDestDir $InstDir
    79. ${Else}
    80.     StrCpy $PortableDestDir $InstDir
    81. ${EndIf}
    82. FunctionEnd
    83.  
    84.  
    85. Function PortableModePageCreate
    86. Call SetModeDestinationFromInstdir ; If the user clicks BACK on the directory page we will remember their mode specific directory
    87. !insertmacro MUI_HEADER_TEXT "Install Mode" "Choose how you want to install ${NAME}."
    88. nsDialogs::Create 1018
    89. Pop $0
    90. ${NSD_CreateLabel} 0 10u 100% 24u "Select install mode:"
    91. Pop $0
    92. ${NSD_CreateRadioButton} 30u 50u -30u 8u "Normal install"
    93. Pop $1
    94. ${NSD_CreateRadioButton} 30u 70u -30u 8u "Portable"
    95. Pop $2
    96. ${If} $PortableMode = 0
    97.     SendMessage $1 ${BM_SETCHECK} ${BST_CHECKED} 0
    98. ${Else}
    99.     SendMessage $2 ${BM_SETCHECK} ${BST_CHECKED} 0
    100. ${EndIf}
    101. nsDialogs::Show
    102. FunctionEnd
    103.  
    104. Function PortableModePageLeave
    105. ${NSD_GetState} $1 $0
    106. ${If} $0 <> ${BST_UNCHECKED}
    107.     StrCpy $PortableMode 0
    108.     StrCpy $InstDir $NormalDestDir
    109. ${Else}
    110.     StrCpy $PortableMode 1
    111.     StrCpy $InstDir $PortableDestDir
    112. ${EndIf}
    113. FunctionEnd
    114.  
    115.  
    116.  
    117. Section
    118. SetOutPath "$InstDir"
    119. ;File "source\myapp.exe"
    120.  
    121. ${If} $PortableMode = 0
    122.     WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${UNINSTKEY}" "DisplayName" "${NAME}"
    123.     WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${UNINSTKEY}" "UninstallString" '"$INSTDIR\uninstall.exe"'
    124.     WriteUninstaller "$INSTDIR\uninstall.exe"
    125. ${Else}
    126.     ; Create the file the application uses to detect portable mode
    127.     FileOpen $0 "$INSTDIR\portable.dat" w
    128.     FileWrite $0 "PORTABLE"
    129.     FileClose $0
    130. ${EndIf}
    131. SectionEnd
    132.  
    133.  
    134. Section Uninstall
    135. DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${UNINSTKEY}"
    136. Delete "$INSTDIR\uninstall.exe"
    137. ;Delete "$INSTDIR\myapp.exe"
    138. RMDir "$InstDir"
    139. SectionEnd
    140.  
     
    YURSHAT нравится это.

Поделиться этой страницей