Вопрос Перемещение формы инсталлятора без рамки

[Le9ent]

Доброго времени суток уважаемые пользователи, хотел у вас узнать следующий момент:
Есть окно инсталлятора, оно без рамки и его фон выполнен с помощью картинки.

WizardForm.BorderStyle:=bsNone;

Т.к. стандартная рамка убрана окно нельзя переместить по площади экрана.
В поиске нашел пример использования одной процедуры:

function ReleaseCapture: Longint; external 'ReleaseCapture@user32.dll stdcall';
procedure LabelOnMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  ReleaseCapture;
  SendMessage(WizardForm.Handle,$0112,$F012,0);
end;

Но проблема в том , что данная процедура работает для изображений (для лейблов и на обычной версии работает процедура) только в расширенной версии компилятора Inno Setup, по некоторым причинам я не хочу его использовать (банально во многих случаях различные антивирусы ругаются на скомпилированный файл и на саму расширенную версию от restools).

Так вот есть ли альтернативный способ или процедура которая могла бы заставить двигать элементы окна (в моем случае изображение) который бы работал для стандартной версии компилятора?

 

[sergey3695]

Пробуй

 

[Le9ent]

Пробуй

Не хочет компилится, ругается на неизвестный тип: TMsg

 

[sergey3695]

Le9ent, Значит только для расширенной. Се ля ви.

 

[Shegorat]

Le9ent
Ну как вариант так
Код

[Setup]
AppName=MyApp
AppVerName=MyApp
DefaultDirname={pf}\MyApp

[Files]
Source: compiler:innocallback.dll; DestDir: {tmp}; Flags: dontcopy

[code]
type
  TCallbackProc = function(h:hWnd;Msg,wParam,lParam:Longint):Longint;
  SHORT = Longint;

const
  WM_SYSCOMMAND = $0112;
  WM_MOUSEMOVE = $0200;
  VK_LBUTTON = 1;
  SC_DRAGMOVE = $F012;
  GWL_WNDPROC = -4;

var
  OldProc: Longint;

function GetKeyState(nVirtKey: Integer): SHORT; external 'GetKeyState@user32.dll stdcall';
function ReleaseCapture: BOOL; external 'ReleaseCapture@user32.dll stdcall';
function SetWindowLong(Wnd: HWnd; Index: Integer; NewLong: Longint): Longint; external 'SetWindowLongA@user32.dll stdcall';
function WndProcCallBack(P:TCallbackProc;ParamCount:integer):LongWord; external 'wrapcallback@files:innocallback.dll stdcall';
function CallWindowProc(lpPrevWndFunc: Longint; hWnd: HWND; Msg: UINT; wParam, lParam: Longint): Longint; external 'CallWindowProcA@user32.dll stdcall';

function AppOnMsg(h: HWND; msg: Longint; wParam, lParam: Longint): Longint;
begin
  if (msg = WM_MOUSEMOVE) and (GetKeyState(VK_LBUTTON) > 0) then
  begin
    ReleaseCapture;
    SendMessage(WizardForm.Handle, WM_SYSCOMMAND, SC_DRAGMOVE, 0); 
  end;

  Result:= CallWindowProc(OldProc, h, msg, wParam, lParam);
end;

procedure InitializeWizard();
begin
  OldProc:= SetWindowLong(WizardForm.Handle, GWL_WNDPROC, WndProcCallback(@AppOnMsg, 4));
end;

procedure DeinitializeSetup();
begin
  SetWindowLong(WizardForm.Handle, GWL_WNDPROC, OldProc);
end;

 

[Le9ent]

Le9ent
Ну как вариант так

Да вот то что нужно.

sergey3695, Shegorat - спасибо вам за помощь.